/*
 *  This EAGLE User Language Program
 */





string dir(int direction)
{
 switch (direction)
    {     
     case PIN_DIRECTION_NC  :return "nc";
     case PIN_DIRECTION_IN  :return "in";
     case PIN_DIRECTION_OUT :return "out";
     case PIN_DIRECTION_IO  :return "i/o";
     case PIN_DIRECTION_OC  :return "oc";
     case PIN_DIRECTION_PWR :return "pwr";
     case PIN_DIRECTION_PAS :return "pas";
     case PIN_DIRECTION_HIZ :return "hiz";
     case PIN_DIRECTION_SUP :return "sup";
    }
}



string fun(int function)
{
 switch (function)
    {     
     case PIN_FUNCTION_FLAG_NONE  :return "none";
     case PIN_FUNCTION_FLAG_DOT   :return "dot";
     case PIN_FUNCTION_FLAG_CLK   :return "clk";
    }
}



string len(int length)
{
 switch (length)
    {     
     case PIN_LENGTH_POINT  :return "point";
     case PIN_LENGTH_SHORT  :return "short";
     case PIN_LENGTH_MIDDLE :return "middle";
     case PIN_LENGTH_LONG   :return "long";
    }
}


string vis(int visible)
{
 switch (visible)
    {     
     case PIN_VISIBLE_FLAG_OFF :return "off";
     case PIN_VISIBLE_FLAG_PAD :return "pad";
     case PIN_VISIBLE_FLAG_PIN :return "pin";
    }
 return "both";
}


string po(int pour)
{
 switch (pour)
    {     
     case POLYGON_POUR_SOLID  :return "solid";
     case POLYGON_POUR_HATCH  :return "hatch";
    }
}


string sh(int shape)
{
 switch (shape)
    {     
     case PAD_SHAPE_SQUARE    :return "square";
     case PAD_SHAPE_ROUND     :return "round";
     case PAD_SHAPE_OCTAGON   :return "octagon";
     case PAD_SHAPE_XLONGOCT  :return "xlongoct";
     case PAD_SHAPE_YLONGOCT  :return "ylongoct";    
    }
}

string adlev(int addlevel)
{
 switch (addlevel)
    {
     case GATE_ADDLEVEL_MUST    :return "must";
     case GATE_ADDLEVEL_CAN     :return "can";
     case GATE_ADDLEVEL_NEXT    :return "next";
     case GATE_ADDLEVEL_REQUEST :return "request";
     case GATE_ADDLEVEL_ALWAYS  :return "always";
    }


}


void pinprint(UL_PIN p)
{
     printf("Pin '%s' %s %s %s r%g %s (%g %g)\n",p.name,dir(p.direction),fun(p.function),len(p.length),p.angle,vis(p.visible),u2mil(p.x),u2mil(p.y));
}



void wireprint(UL_WIRE w)
{
 printf("Layer %d;\nWire %g (%g %g) (%g %g);\n",w.layer,u2mil(w.width),u2mil(w.x1),u2mil(w.y1),u2mil(w.x2),u2mil(w.y2));
}


void textprint(UL_TEXT t)
{
 char mir='m';
 if (t.mirror==0) mir='r';
 printf("Layer %d;\nchange size %g;\nchange ratio %d;\n",t.layer,u2mil(t.size),t.ratio);
 printf("Text '%s' %c%g (%g %g)\n",t.value,mir,t.angle,u2mil(t.x),u2mil(t.y));
}


void arcprint(UL_ARC a)
{
 string ort="cw";
 if (a.angle1<a.angle2)ort="ccw";
 printf("layer %d;\nArc %s %g (%g %g) (%g %g) (%g %g);\n",a.layer,ort,u2mil(a.width),u2mil(a.x1),u2mil(a.y1),u2mil(2*a.xc-a.x1),u2mil(2*a.yc-a.y1),u2mil(a.x2),u2mil(a.y2));
}



void circleprint(UL_CIRCLE c)
{
 printf("layer %d;\nCircle %g (%g %g) (%g %g);\n",c.layer,u2mil(c.width),u2mil(c.x),u2mil(c.y),u2mil(c.x+c.radius),u2mil(c.y));
}


void rectangleprint(UL_RECTANGLE r)
{
 printf("Layer %d;\nRect (%g %g) (%g %g);\n",r.layer,u2mil(r.x1),u2mil(r.y1),u2mil(r.x2),u2mil(r.y2));
}


void polygonprint(UL_POLYGON p)
{
 int xk,yk;
 string orp="on";
 string term="on";
 if (p.orphans==0) orp="off"; 
 if (p.thermals==0) term="off";
 printf("Change Isolate %g;\n",u2mil(p.isolate));
 printf("Change Spacing %g;\n",u2mil(p.spacing));
 printf("Change Pour %s;\n",po(p.pour));
 printf("Change Orphans %s;\n",orp);
 printf("Change Thermals %s;\n",term);
 printf("Change Layer %d;\n",p.layer);
 printf("Polygon %g ",u2mil(p.width));
 p.wires(w)
      {
       printf("(%g %g) ",u2mil(w.x1),u2mil(w.y1));
       xk=w.x2;
       yk=w.y2;
      }
 printf("(%g %g);\n",u2mil(xk),u2mil(yk));
}


void contactprint(UL_CONTACT c)
{
 UL_PAD p=c.pad;
 printf("Change drill %g;Pad '%s' %s %g (%g %g);\n",u2mil(p.drill),p.name,sh(p.shape),u2mil(p.diameter),u2mil(p.x),u2mil(p.y));
      
}



void devprint(UL_DEVICE dev)
{
 printf("Prefix '%s';\n",dev.prefix);
 printf("Value %s;\n",dev.value);
 if (dev.package) printf("Package '%s';\n",dev.package.name); 
 dev.gates(g)
      {
       printf("Add %s '%s' %s %d (%g %g);\n",g.symbol.name,g.name,adlev(g.addlevel),g.swaplevel,u2mil(g.x),u2mil(g.y));
       if (dev.package) g.symbol.pins(p)
            {
             printf("Connect '%s.%s' '%s';\n",g.name,p.name,p.contact.name);
            }
      }

}


void layerprint(UL_LIBRARY lbr)
{
 printf("Grid mil 100 1 on;\n");
 lbr.layers(L)
     {
      printf("Layer %d %s\n",L.number,L.name);
     }
} 




/***************************************************************************
                          MAIN
//////////////////////////////////////////////////////////////////////////*/

output("d:\export.scr")
schematic(sch) 
{
 sch.libraries(lbr)
    {
     output(filesetext(lbr.name, ".scr")) 
               {
                layerprint(lbr);
                lbr.symbols(sym)
                    {
                     printf("\nEdit %s.sym\n",sym.name);
                     sym.pins(p)
                          {
                           pinprint(p);
                          }
                     sym.wires(w)
                          {
                           wireprint(w);
                          }
                     sym.texts(t)
                          {
                           textprint(t);
                          }
                     sym.arcs(a)
                          {
                           arcprint(a);
                          }
                     sym.circles(c)
                          {
                           circleprint(c);
                          }
                     sym.rectangles(r)
                          {
                           rectangleprint(r);
                          }
                     sym.polygons(p)
                          {
                           polygonprint(p);
                          }
                    }



                lbr.packages(pac)
                    {
                     printf("\nEdit %s.pac\n",pac.name);
                     pac.contacts(c)
                          {
                           contactprint(c);
                          }
                     pac.wires(w)
                          {
                           wireprint(w);
                          }
                     pac.texts(t)
                          {
                           textprint(t);
                          }
                     pac.arcs(a)
                          {
                           arcprint(a);
                          }
                     pac.circles(c)
                          {
                           circleprint(c);
                          }
                     pac.rectangles(r)
                          {
                           rectangleprint(r);
                          }
                     pac.polygons(p)
                          {
                           polygonprint(p);
                          }
                   }


                lbr.devices(dev) 
                   {
                    printf("\nEdit %s.dev\n",dev.name);
                    devprint(dev);
                   }
               
               }
         

    }
}